Уроки Flash: Создание простого флеш-сайта

package complex{/*Определяем принадлежность к пакету complex*/
import flash.display.*;/*Подключаем пакет для работы с дисплеем*/
import flash.ui.*;/*пакет содержащий классы необходимые для работы с мышью и клавиатурой*/
import flash.events.*;/*Подключение пакета контролирующего события, в духе нажатие мыши и т.д.*/
 
public class Animation{/*Объявляем класс.*/
public var TF:int;/*Вводим новую переменную ее мы будем использовать для хранения кол-ва кадров в анимации данного символа*/
public var CF:int = 1;/*Вводим новую переменную ее мы будем использовать для хранения номера текущего кадра анимации*/
public var over:Boolean = false;/*Логическая переменная, ее будем использовать для того чтобы Функция производящая анимацию знала какое произошло событие*/
public var MenuLabel:String;/*Очередная переменная, на этот раз строка, ей мы передадим имя кнопки, которое было полученно при вызове класса*/
public function anim(but:Sprite,MLabe:String){/*Функция которая будет вызываться из основного класса, в ней мы добавим "слушателей" необходимых событий и присвоим полученное значение строки заранее заготовленной переменной*/

MenuLabel = MLabe;/*Присваиваем переменной полученное значение имени этого пункта меню*/

but.addEventListener(MouseEvent.MOUSE_OVER, roll);/*Добавляем "слушателя" который будет отслеживать наведение курсора на Спрайт и вызывать при этом функцию roll*/
but.addEventListener(MouseEvent.MOUSE_OUT, rollout);/*Добавляем "слушателя" который будет отслеживать убирание курсора с Спрайта и вызывать при этом функцию rollout*/
but.addEventListener(Event.ENTER_FRAME, render);/*Добавляем слушателя для того чтобы функция render выполнялась каждый кадр тем самым производя анимацию в случае необходимости*/
}
function roll(events:Event):void{/*Функция которая вызывается при наведении мыши на кнопку*/
over=true; /*Ранее созданая нами логическая переменная получает значение true, что свидетельствует о том, что надо производить линейную анимацию символа*/
}  

function rollout(events:Event){/*Функция которая вызывается при убирании мыши с кнопки*/
over=false; /*Ранее созданая нами логическая переменная получает значение false, что свидетельствует о том, что надо производить обратную анимацию символа*/
}

var firstTime:Boolean=false;/*Объявляем логическую переменную. Ее мы будем использовать в функции render, чтобы обеспечить однократное выполнение части ее содержимого*/
function render(events:Event){/*Функция которая выполняется каждый кадр*/
if(!firstTime){/*Проверяем значение логической переменной firstTime, если оно равно false, что значит, что содержимое этого условия еще не выполнялось, то программа переходит к выполнению команд внутри условного оператора*/
TF = events.target.totalFrames-1;/*Наша переменная для хранения кол-ва кадров получает значение кадров в анимации -1 кадр. Отнимаю один кадр т.к. у текстового поля также имеется своя анимация и естественно ключевой кадр на конце. Если анимация дойдет, до этого ключевого кадра, то содержимое текстового поля переопределится и затрется надпись с названием кнопки.*/
events.target.stop();/*Останавливаем воспроизведение анимации кнопки*/
events.target.ide.text=MenuLabel;/*Присваиваем текстовому полю расположенному в кнопке полученное при вызове основной функции значение*/
firstTime=true;/*Присваиваем логической переменной firstTime значение true, чтобы содержимое условного оператора не выполнялось больше в дальнейшем*/
}
if((over)&&(CF<TF)){/*Условный оператор, суть его примерно такова, если мышь наведена на кнопку и текущий кадр анимации не последний то,*/
CF++;/*Увеличиваем значение текущего кадра на 1*/
events.target.gotoAndStop(CF);/*и переходим к этому значению*/
}

if((!over)&&(CF>1)){/*Если мышь убрали и текущий кадр анимации не является первым*/
CF--; /*Уменьшаем значение текущего кадра на 1*/
events.target.gotoAndStop(CF);/*и переходим к этому значению*/
}
}

}
}

.mainFormat {
font-family: Comic Sans MS;
font-size: 20;
color:#333333;
}
h1 {
font-family: Georgia;
font-size: 22;

}
h2 {
font-family: Georgia;
font-size: 20;

}
a:link {
color:#E37302;
font-size: 17;
text-decoration:underline;
}

package complex{/*Определяем принадлежность к пакету complex*/
import flash.display.*;/*Подключаем пакет для работы с дисплеем*/
import flash.ui.*;/*пакет содержащий классы необходимые для работы с мышью и клавиатурой*/
import flash.events.*;/*Подключение пакета контролирующего события, в духе нажатие мыши и т.д.*/
import flash.net.*;/*Этот пакет необходим для загрузки различной информации из вне*/
import flash.text.*;/*Пакет содержащий классы необходимые для работы с текстом*/

public class contentLoader{/*Объявляем класс.*/

public var loader:URLLoader = new URLLoader();/*Создаем новый загрузчик, его мы будем использовать для загрузки содержимого текстовых файлов*/
public var loader2:URLLoader = new URLLoader();/*Создаем новый загрузчик, его мы будем использовать для загрузки содержимого CSS-Файла*/

public var tx:TextField;/*Создаем новый обект текстового поля которому будет присвоено основное текстовое поле проекта*/
public var wa:String;/*Новая переменная строка, ей будет присвоен путь до текстового файла с информацией*/
public var formatFile:String;/*Еще одна строка, она получит в качестве значения путь до CSS-файла*/

public var l:TextField;/*Это текстовое поле будет связано с текстовым полем в котором отображается название текущей страницы*/
public var lC:String;/*Эта строка получит значение этого названия*/
public var lF:TextFormat;/*А это текстовый формат который будет применен к названию "страницы"*/

public var scrLine:Sprite;/*Линия под скролом*/
public var scrDrag:Sprite;/*ползунок от скрола*/
public var flStage:Sprite;/*Созданая в основном классе невидимая кнопка*/
/*Последние три Спрайта в этом классе напрямую никак не используются, а просто передаются дальше в качестве параметров при вызове класса скрола*/

public function loadInformationOnPress(mc:Sprite, txt:TextField, way:String, format:String, lab:TextField, laC:String, laF:TextFormat, scrl:Sprite, scrd:Sprite, flst:Sprite)
{/*Функция для загрузки контента по нажатии на кнопку*/

l=lab;
lC=laC;
lF=laF;
tx=txt;
wa=way;
formatFile=format;
scrLine=scrl;
scrDrag=scrd;
flStage=flst;
/*Переприсвоение полученных функцией в качестве параметров значений в заранее подготовленные переменные, какая переменная что значит описанно выше*/

mc.addEventListener(MouseEvent.CLICK, callInformation);/*Добавляем к кнопке "слушателя" который по "клику" на кнопке будет вызывать функцию callInformation*/

}

public function callInformation(events:Event){/*Функция которая вызывается при "клике" по кнопке, функция содержимое которой по сути представляет из себя просто вызов двух других функций*/

loadInformation(tx,wa,formatFile,scrLine,scrDrag,flStage);/*Вызов функции производящей загрузку информации, параметры передаваемые этой функции разобраны в оописании основного класса программы*/
setLabel(l,lC,lF);/*Функция которая выводит название текущей страницы и оформляет его*/
/*Параметры:
1. Текстовое поле.
2. Значение которое ему надо присвоить(строка).
3. Формат текста который следует к нему применить.*/
}
function setLabel(la:TextField,laCont:String,labForm){/*Функция для выведения названия текущей страницы*/
la.text=laCont;/*Присваиваем необходимое значение*/
la.setTextFormat(labForm);/*Устанавливаем формат*/
}

public function loadInformation(txt:TextField,way:String, format:String,scrl:Sprite,scrd:Sprite,flst:Sprite){/*Функция которая начинает загрузку контента*/
tx=txt;
scrLine=scrl;
scrDrag=scrd;
flStage=flst;
formatFile=format;
/*Переприсвоение полученных функцией в качестве параметров значений в заранее подготовленные переменные, какая переменная что значит описанно выше*/

var contentName:URLRequest = new URLRequest(way);/*Новый запрос для загрузки*/
loader.addEventListener(Event.COMPLETE, contentLoaded);/*Цепляем к ранее созданому загрузчику слушателя на окончание файла*/
loader.load(contentName);/*Начинаем загрузку текстового файла*/
}

function contentLoaded(events:Event){/*Функция которая вызывается когда содержимое текстового файла загружено*/
var req:URLRequest = new URLRequest(formatFile); /*Еще один запрос для загрузки, на этот раз CSS-файла*/
loader2.addEventListener(Event.COMPLETE, onCSSFileLoaded); /*Добавляем к загрузчику для CSS-файла "слушателя" на окончание загрузки*/
loader2.load(req); /*Начинаем загрузку CSS-Файла*/
}

public function onCSSFileLoaded(event:Event):void /*Функция по окончанию загрузки CSS-файла*/
{
var sheet:StyleSheet = new StyleSheet(); /*Новый объект CSS*/
sheet.parseCSS(loader2.data); /*Переносим полученное содержимое CSS-Файла в специальный объект только-что созданный нами*/
tx.styleSheet = sheet; /*Включаем форматирование содержимого текстового поля при помощи объекта с содержимым из нашего CSS-файла*/
tx.htmlText = loader.data;/*Присваиваем текстовому полю текст полученный из текстового файла немного ранее*/

var myScrollBarer:ScrollBarer = new ScrollBarer();/*Экземпляр класса скробара*/
myScrollBarer.addScroll(tx,scrLine,scrDrag,flStage);/*Вызываем функцию скролбара*/
/*Параметры:
1. Текстовое поле к которому цепляется скрол
2. Линия по которой будем перемещать ползунок.
3. Сам ползунок.
4. Невидимая кнопка размером со сцену, которую мы создавали в основном классе.
*/
}

}
}

package complex{/*Определяем принадлежность к пакету complex*/
import flash.display.*;/*Подключаем пакет для работы с дисплеем*/
import flash.ui.*;/*пакет содержащий классы необходимые для работы с мышью и клавиатурой*/
import flash.events.*;/*Подключение пакета контролирующего события, в духе нажатие мыши и т.д.*/
import flash.text.*;/*Пакет содержащий классы необходимые для работы с текстом*/
import flash.geom.*;/*Пакет содержит классы необходимые при создании геометрических фигур*/
public class ScrollBarer{/*Объявляем класс.*/

public var sost:Boolean;/*Логическая переменная будет использоваться при отслеживании нажат или отпущен ползунок*/
public var scrLine:Sprite;/*Новый спрайт, ему будет передана линия под скролом*/
public var scrDrag:Sprite;/*Новый спрайт, ему будет передан ползунок скрола*/
public var Text:TextField;/*Текстовое поле к которому будем цеплять скрол*/

public var dragPart:Rectangle;/*Объявляемый новый "прямоугольник", его мы будем использовать для ограничения области перемещения ползунка*/

public var firstTime:Boolean=false;/*Логическая переменная будет использовна для однократного использования фрагмента кода в обработчикe ENTER_FRAME, подобный ход мы уже применяли в классе отвечающем за анимацию кнопочек*/
public var lScroll:Boolean=false;/*Очередная булеана, будет использована при создании скролирования по нажатии на ограничивающую линию скрола*/

public function addScroll(txt:TextField,scroll_line:Sprite, scroll_Drag:Sprite,fullStage:Sprite){/*Функция которая будет вызываться для создания скрола, параметры описаны в разборе класса contentLoader*/
scrLine = scroll_line;
scrDrag = scroll_Drag;
Text=txt;
/*Переприсвоение полученных функцией в качестве параметров значений в заранее подготовленные переменные, какая переменная что значит описанно выше*/
dragPart=new Rectangle(scrLine.x, scrLine.y, 0, scrLine.height-scrDrag.height);/*Настраиваеам прямоугольник для ограничения области перемещения ползунка, координаты соовпадают с координатами линии скрола, ширина равна нулю т.к. нам не нужны смещения по оси Х, высота равняется высоте линии минус высота ползунка, вычитаем высота ползунка чтобы он останавливался когда его нижний край дойдет до конца ограничивающей линии, а не когда он весь выйдет за ее пределы*/

scroll_Drag.addEventListener(MouseEvent.MOUSE_DOWN, startMove);/*"слушатель" для ползунка реагирующий на его нажатие*/
scroll_Drag.addEventListener(MouseEvent.MOUSE_UP, stopMove);/*"слушатель" ползунка реагирующий на отпускние мыши на нем*/
/*Но ведь отжать кнопку мыши можно не только на ползунке, но и скажем на текстовом поле или где-то просто на свободной области, поэтому надо добавить еще несколько слушателей, вот здесь то нам и понадобилась наша невидимая кнопочка*/
fullStage.addEventListener(MouseEvent.MOUSE_UP, stopMove);/*собственно "слушатель" для якобы свободной области сцены(нашей невидимой кнопки)*/
txt.addEventListener(MouseEvent.MOUSE_UP, stopMove);/*"слушатель" на отпускание кнопки мышки над текстовым полем*/
scroll_line.addEventListener(MouseEvent.MOUSE_DOWN, lineWheelStart);/*отслеживаем нажатие на линию скрола*/
scroll_line.addEventListener(MouseEvent.MOUSE_UP, lineWheelFinish);/*отслеживаем отпускание кнопки мыши над линией скрола*/
scroll_Drag.addEventListener(Event.ENTER_FRAME, render);/*"слушатель" события ENTER_FRAME для нашего ползунка, указаная в параметрах функция будет вызываться каждый кадр*/
fullStage.addEventListener(MouseEvent.MOUSE_WHEEL, wheelScroll);/*Отслеживание колесика мыши над невидимой кнопкой*/
txt.addEventListener(MouseEvent.MOUSE_WHEEL, wheelScroll);/*Отслеживание колесика мыши над текстовым полем*/

}

function startMove(events:MouseEvent):void{/*Функция по нажатию на ползунок*/
sost=true;/*Булеана получает значение true, значит ползунок нажат*/
scrDrag.startDrag(false,dragPart);/*Начинаем перемещение ползунка за мышью в пределах, очерченных нами ранее при создании прямоугольника*/
}
function stopMove(events:Event):void{/*Функция по отпускании кнопки мышки*/
sost=false;/*Булеана получает значение false, значит ползунок отпустили*/
lScroll=false;/*Не забываем, что у нас есть еще такая вещь, как скрол по нажатии, на линию скролбара, так что его здесь тоже бы отключить надо*/
scrDrag.stopDrag();/*Прекращаем передвижение ползунка*/
}

function render(events:Event){/*Функция которая выполняется каждый кадр*/
if(!firstTime){/*Проверка на то который раз выполняется этот кусочек кода.*/
scrDrag.y=scrLine.y;/*Перебрасываем ползунок в начальное положение, это необходимо, чтобы при открытии каждой новой "страницы" полузнок стоял вверху, а страница отображалась сначала, а не сразу открывалсь где-нибудь по середине*/
firstTime=true;/*Ставим галочку, что все уже выполнено и выполянть еще раз не надо*/
if(Text.maxScrollV<3){/*Проверяем размер загруженного контента*/
scrDrag.visible=false;/*если скролбар не нужен - скрываем его*/
scrLine.visible=false;
}else{/*нужен?*/
scrDrag.visible=true;/*отображаем скролбар*/
scrLine.visible=true;  
 }
}
if(!sost){events.target.gotoAndStop(1);}else{events.target.gotoAndStop(2);}/*В зависимости от того нажат или нет ползунок переходим на разные кадры. Если нет, то на первый. Да - на второй. Это необходимо для изменения вида скрола по нажатии.*/
 
Text.scrollV = Math.round(((scrDrag.y - scrLine.y)/(scrLine.height-scrDrag.height))*Text.maxScrollV);/*Изменяем скроллинг текста в зависимости от положения ползунка, формула не сложная спокойно выводится на листике карандашиком*/

if(lScroll){/*Если нажата линия скрола*/
if(scrLine.y+scrLine.mouseY-scrDrag.height>scrDrag.y){/*Если нажато ниже, чем находится ползунок*/
scrDrag.y+=4;}/*двигаемся вниз*/
if(scrLine.y+scrLine.mouseY<scrDrag.y){/*Если нажато выше, чем находится ползунок*/
scrDrag.y-=4;}/*двигаемся вверх*/
}

if(scrDrag.y<scrLine.y){scrDrag.y=scrLine.y}
if(scrDrag.y>scrLine.y+scrLine.height-scrDrag.height){scrDrag.y=scrLine.y+scrLine.height-scrDrag.height}
/*Две строки выше не позволяют ползунку покидать пределы ограничивающей линии*/
}  

function wheelScroll(events:MouseEvent){/*функция при использовании колесика*/
scrDrag.y+=events.delta*-3;/*Изменяем координату ползунка в зависимости от силы вращения, это значение как и в АС 2.0 передается в числах кратным трем.*/
}

function lineWheelStart(events:Event){/*функция по нажатии на направляющую линию*/
lScroll=true;/*true, значит линия нажата и пора предпринимать соответсвующие действия*/
}
function lineWheelFinish(events:Event){
lScroll=false;/*false, перестаем менять положение ползунка*/
}  

}
}